Documentation de Gambas

Dir

Tableau de noms de fichiers = Dir ( Répertoire AS String

  [ , Canevas AS String , Filtre AS Integer ] ) AS String[]

Retourne un tableau de chaînes de caractère qui contient les noms des fichiers situés dans Répertoire et qui correspondent au Canevas et au Filtre.

Le canevas peut contenir les même caractères génériques que l'opérateur LIKE. Si aucun canevas n'est spécifié, tous les fichiers et répertoires sont retournés.

Le filtre spécifie quel type de fichiers seront retournés, en indiquant un type ou une combinaison constantes type de fichier. Si Filtre n'est pas spécifié, tous les fichiers et répertoires sont retournés.

Les Noms de fichier retournés sont relatifs, ils ne contiennent pas le répertoire de recherche.

Exemple

' Affiche les images png contenues dans un répertoire, par ordre alphabétique

SUB AfficheRepertoire(Repertoire AS String)

  DIM Fichier AS String

  FOR EACH Fichier IN Dir(Repertoire, "*.png").Sort()
    PRINT Fichier
  NEXT

END

  'Affiche tous les fichiers visibles dans le répertoire de l'utilisateur.

  DIM fileName AS String

  FOR EACH fileName IN Dir(User.Home, "[^.]*")
    PRINT fileName
  NEXT

  'Affiche le nom des images png et jpeg présents dans le répertoire de l'utilisateur.

  DIM directory AS String
  DIM files AS String[]
  DIM fileName AS String
  directory = User.Home
  files = Dir(directory, "*.png")
  files.Insert(Dir(directory, "*.jpg"))
  files.Insert(Dir(directory, "*.jpeg"))

  FOR EACH fileName IN files
    PRINT fileName
  NEXT

  'Affiche seulement les fichiers présents dans le répertoire de l'utilisateur.

  DIM fileName AS String

  FOR EACH fileName IN Dir(User.Home, "*", gb.File)
    PRINT fileName
  NEXT

  'Affiche seulement les sous répertoires présents dans le répertoire de l'utilisateur.

  DIM directoryName AS String

  FOR EACH directoryName IN Dir(User.Home, "*", gb.Directory)
    PRINT directoryName
  NEXT

  'Affiche tous les sous répertoires visibles dans le répertoire de l'utilisateur.

  DIM directoryName AS String

  FOR EACH directoryName IN Dir(User.Home, "[^.]*", gb.Directory)
    PRINT directoryName
  NEXT

  'Liste les périphériques système.

  DIM deviceName AS String

  FOR EACH deviceName IN Dir("/dev", "*", gb.Device)
    PRINT deviceName
  NEXT

Voir aussi

Fonctions associées aux fichiers et répertoires, Chemins de Fichiers & Répertoires